voici un petit bout de code qui convertit les fichiers CSV en un seul fichier au format GPX.
Le code est commenté et personnalisable. J'ai par exemple supprimé les pays qui ne me conviennent pas et les types de radars qui ne m'intéressent pas.
Mode d'emploi :
Pré-requis : installer le logiciel GPSBabel sur votre ordinateur.
1- Décompresser l'archive des fichiers radars (disponible ici) dans un dossier.
2- Copier le code suivant dans ce même dossier
3- Exécuter le code
4- Le fichier résultat s'appelle zdd.gpx
Code : Tout sélectionner
@echo off
rem Suppression des fichiers inutiles : Suisse, Allemagne, Grande-Bretagne, Luxembourg, Pays-Bas, Pologne, Suede
rem A personnaliser
del /Q BE*.csv
del /Q CH*.csv
del /Q DE*.csv
del /Q GB*.csv
del /Q LU*.csv
del /Q NL*.csv
del /Q PL*.csv
del /Q SE*.csv
rem Suppression des radars Temporaires, Mobiles et Chantiers
del /Q *Temporaire*.csv
del /Q *Chantier*.csv
del /Q *Mobile*.csv
rem Suppression des fichiers résultats
del /Q "Zones de Danger.csv"
del /Q "Zones de Danger.txt"
rem Traitement
setlocal enabledelayedexpansion
echo latitude , longitude , label>"Zones de Danger.txt"
rem Boucle sur tous les fichiers CSV du dossier courant
for /f "usebackq tokens=1-3 delims=," %%I in (`type *.csv`
) do (
if "%%K" NEQ "" (
set L=%%J,%%I,%%K
rem Suppression de la chaine AD : Andorre
rem suppression en debut de chaine
set L=!L:AD =!
rem suppression en milieu et fin de chaine
set L=!L: AD=!
rem Suppression de la chaine ES : Espagne
set L=!L:ES =!
set L=!L: ES=!
rem Suppression de la chaine FR : France
set L=!L:FR =!
set L=!L: FR=!
rem Suppression de la chaine IT : Italie
set L=!L:IT =!
set L=!L: IT=!
rem Suppression de la chaine PT : Portugal
set L=!L:PT =!
set L=!L: PT=!
echo !L!>>"Zones de Danger.txt"
)
)
ren "Zones de Danger.txt" "Zones de Danger.csv"
rem conversion du fichier CSV en format GPX
"C:\Program Files (x86)\GPSBabel\gpsbabel.exe" -t -i csv -f "Zones de Danger.csv" -o gpx -F zdd.gpx
crédits : je me suis inspiré du code trouvé ICI